/*
 *  Onomatopoeettinen alkoholiliike -- AmigaE-versio
 *  Idea Psilonilta, joka varasti sen Ionilta, joka varasti sen Rennexiltä.
 *  Perjantai-illan hetken hukkasi tätä säätäen Piru, tais olla Elokuu 2002.
 *
 *  © 2002 Harry "Piru" Sintonen
 */

-> eläinten yliluokka

OBJECT elucka PRIVATE
  nimi:PTR TO CHAR
  sano:PTR TO CHAR
ENDOBJECT

PROC init(i_nimi, i_sano) OF elucka
  self.nimi := i_nimi
  self.sano := i_sano
ENDPROC

PROC kuinkasanoo(teksti) OF elucka
  DEF isonimi[10]:STRING

  StrCopy(isonimi, self.nimi)
  isonimi[0] := isonimi[0] AND $df

  PrintF('\n\s sanoo \s, \s\n' +
         '\s sanoo \s, \s\n' +
         'Kuinka \s sanoo, kuinka \s sanoo,\n' +
         'kuinka \s sanoo \s?\n' +
         '\s sanoo \s, \s\n',
         isonimi, self.sano, self.sano,
         isonimi, self.sano, self.sano,
         self.nimi, self.nimi,
         self.nimi, teksti,
         isonimi, self.sano, self.sano)
ENDPROC

-> eläinluokat

OBJECT gorilla OF elucka PRIVATE
ENDOBJECT

PROC kuinkasanoo(teksti) OF gorilla
  PrintF('\nGorilla sanoo yääärrauhrhha\n' +
         'Gorilla sanoo yhhrräähh rhähhrrääh\n' +
         'Kuinka gorilla sanoo, kuinka gorilla sanoo,\n' +
         'kuinka gorilla sanoo \s?\n' +
         'Gorilla sanoo öährrh - Bundolo!\n',
         teksti)
ENDPROC

OBJECT kiiski OF elucka PRIVATE
ENDOBJECT

PROC kuinkasanoo(teksti) OF kiiski
  SUPER self.kuinkasanoo(teksti)
  PrintF('... ..., ... ...\n')
ENDPROC

OBJECT siittio OF elucka PRIVATE
ENDOBJECT

PROC kuinkasanoo(teksti) OF siittio
  SUPER self.kuinkasanoo(teksti)
  PrintF('ptlqm ptlqm, ptlqm ptlqm, ptl ptl, qm, ptlqm ptlqm...\n')
ENDPROC


-> suoritus alkaa tästä

PROC main()

  DEF kana:PTR TO elucka
  DEF karhu:PTR TO elucka
  DEF gorilla:PTR TO gorilla
  DEF kirahvi:PTR TO elucka
  DEF kiiski:PTR TO kiiski
  DEF siittio:PTR TO siittio

  NEW kana.init('kana', 'kot kot kot')
  NEW karhu.init('karhu', 'mur mur mur')
  NEW gorilla.init('gorilla', NIL)
  NEW kirahvi.init('kirahvi', 'öri öri öri')
  NEW kiiski.init('kiiski', '... ...')
  NEW siittio.init('siittiö', 'ptlqm')

  -> laulu alkaa!

  PrintF('\nONOMATOPOEETTINEN ALKOHOLILIIKE\n\n')

  kana.kuinkasanoo('Canaba')
  karhu.kuinkasanoo('Karhu')
  gorilla.kuinkasanoo('Carillo')

  PrintF('\nKetulla on krapula, niin myös madolla.\n')
  PrintF('Kaikki ne voit tavata Alkon jonossa!\n')

  kirahvi.kuinkasanoo('Kahvi - likööri')

  PrintF('\nSiili käyttää aineita, niin myös etana.\n')
  PrintF('Heitä et voi tavata Alkon jonossa!\n')

  kiiski.kuinkasanoo('Whisky')
  siittio.kuinkasanoo('I love you')

ENDPROC